Vous recherchez une formation ? Retrouvez-nous sur aei-formation.fr
Solutions industrielles Industrie 4.0
Un projet, contactez-nous !
Accueil > Tutoriel - Lina Procédé - 05/2024 > Tutoriel Siemens > 9. Annexes > 9.5 SCL FC568_SEQ_ARCHIVAGE
Procédé

Tutoriel - Lina Procédé - 05/2024

9.5 SCL FC568_SEQ_ARCHIVAGE

//RAZ STRING D ETAT ETAPES
"DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := '                                                                                ';
"DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := '                                                                                ';



REGION SEQ EN-TÊTE


//INIT SEQUENCE COM FTP / PAS DE RAZ TAB CAR COM FTP EN COURS
IF ("DB810_GESTION_IHM".INIT_SEQ OR "DB562_SEQ_PROG_EN_COURS".SEQ.CMD02_00)
    AND ("DB570_SEQ_COM_FTP".SEQ.INT02 < 5 AND "DB570_SEQ_COM_FTP".SEQ.INT03 < 5) THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 0;
END_IF;


//INIT SEQUENCE SI DEFAUT COM FTP / RAZ TAB ARCHIVAGE CAR COM EN DEF
IF "DB562_SEQ_PROG_EN_COURS".SEQ.CMD02_00
    AND ("DB570_SEQ_COM_FTP".SEQ.INT02 >= 5 OR "DB570_SEQ_COM_FTP".SEQ.INT03 >= 5) THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 6000;
END_IF;


//RAZ DES VARIABLES
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 0 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
    "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;


    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_00 := 0;    //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_01 := 0;    //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_02 := 0;    //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_03 := 0;    //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_04 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_05 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_06 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_07 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_08 := 0;    //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_09 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_10 := 0;   // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_11 := 0;   // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_12 := 0;   //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_13 := 0;   // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_14 := 0;   //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD01_15 := 0;   //


    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_00 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_01 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_02 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_03 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_04 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_05 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_06 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_07 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_08 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_09 := 0;    // 
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_10 := 0;   //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_11 := 0;   //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_12 := 0;   //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_13 := 0;   //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_14 := 0;   //
    "DB568_SEQ_ARCHIVAGE".SEQ.CMD02_15 := 0;   //


    "DB568_SEQ_ARCHIVAGE".SEQ.INT01 := 0;     //
    "DB568_SEQ_ARCHIVAGE".SEQ.INT02 := 0;     // 
    "DB568_SEQ_ARCHIVAGE".SEQ.INT03 := 0;     // 
    "DB568_SEQ_ARCHIVAGE".SEQ.INT04 := 0;     // 
    "DB568_SEQ_ARCHIVAGE".SEQ.INT05 := 0;     //


    "DB568_SEQ_ARCHIVAGE".SEQ.ETAT01 := 0;


    IF "REPRISE_API_OK" THEN
        "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 10;
    END_IF;
END_IF;


//SAUT SI AU  POUR FIGER SEQUENCE
IF "Tjrs_0" THEN
    GOTO L999;
END_IF;


//DEMARRAGE DE LA SEQUENCE
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 0 AND "REPRISE_API_OK" THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 10;
END_IF;


//INCREMENTATION TEMPO
IF "BIT_100ms" AND "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS < 32766 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS + 1;
END_IF;
IF "BIT_1s" AND "DB568_SEQ_ARCHIVAGE".SEQ.T_1S < 32766 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := "DB568_SEQ_ARCHIVAGE".SEQ.T_1S + 1;
END_IF;
END_REGION
//
//---------------------------------------------------------------------------------------------------------
REGION INIT PARAM
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 10 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Attente de demande de synchro demarrage process';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := 'Demande de synchro recue';
END_IF;


(*ATTENTE DE DEMANDE DE SYNCHRO DEMARRAGE*)
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 10 AND "DB200_SEQ_PROCESS".SEQ.NUM_ETAPE = 40 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 15;
END_IF;
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 15 AND "DB200_SEQ_PROCESS".SEQ.NUM_ETAPE <> 40 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 20;
END_IF;


// 20 : Initialisation des parametres
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 20 THEN


    //raz tab archivage
    FOR #i := 1 TO 3600 DO
        "DB568_SEQ_ARCHIVAGE".SEQ.INT01 := #i;
        "DB580_ARCHIVAGE_PARAM_02".Archive[#i] := 0.0;
        "DB581_ARCHIVAGE_PARAM_04".Archive[#i] := 0.0;
    END_FOR;


    //*Parametres
    "DB569_PARAM_SEQ_ARCHIVAGE".index_max := 3600;
    "DB569_PARAM_SEQ_ARCHIVAGE".tps_def_com := 90;
    "DB569_PARAM_SEQ_ARCHIVAGE".Tps_Echantillonnage := T#5s;
    "DB569_PARAM_SEQ_ARCHIVAGE".tps_echantillonnage_int := TIME_TO_INT("DB569_PARAM_SEQ_ARCHIVAGE".Tps_Echantillonnage) / 1000;
    "DB569_PARAM_SEQ_ARCHIVAGE".Index_att_def := "DB569_PARAM_SEQ_ARCHIVAGE".tps_def_com / "DB569_PARAM_SEQ_ARCHIVAGE".tps_echantillonnage_int;


    //* Parametre echantillonage
    "DB580_ARCHIVAGE_PARAM_02".Echantillonage := "DB569_PARAM_SEQ_ARCHIVAGE".Tps_Echantillonnage;
    "DB581_ARCHIVAGE_PARAM_04".Echantillonage := "DB569_PARAM_SEQ_ARCHIVAGE".Tps_Echantillonnage;


    (*Mise à 1 de l'index*)
    "DB569_PARAM_SEQ_ARCHIVAGE".index := 1;


    (*Etat séquence*)
    "DB568_SEQ_ARCHIVAGE".SEQ.ETAT01 := 1;


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Initialisation des parametres';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := '1';


    IF "Tjrs_1" THEN
        "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 100;
    END_IF;
END_IF;
END_REGION


REGION 100 : Gestion du premier index
// 100 : Verification index = 1
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 100 THEN


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Verification valeur index depart';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := 'Index = 1';


    //* Sauvegarde l'heure sur premier index
    IF "DB569_PARAM_SEQ_ARCHIVAGE".index = 1 THEN
        "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 200;
    END_IF;
END_IF;


// 200 :Sauvegarde avec le premier index
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 200 THEN


    "DB580_ARCHIVAGE_PARAM_02".Heure_debut := "DB810_GESTION_IHM".Date_heure_en_cours;
    "DB581_ARCHIVAGE_PARAM_04".Heure_debut := "DB810_GESTION_IHM".Date_heure_en_cours;


    "DB580_ARCHIVAGE_PARAM_02".Archive["DB569_PARAM_SEQ_ARCHIVAGE".index] := "DB200_SEQ_PROCESS".SEQ.INT03;
    "DB581_ARCHIVAGE_PARAM_04".Archive["DB569_PARAM_SEQ_ARCHIVAGE".index] := "DB200_SEQ_PROCESS".SEQ.INT04;


    "DB569_PARAM_SEQ_ARCHIVAGE".index := "DB569_PARAM_SEQ_ARCHIVAGE".index + 1;


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Sauvegarde avec le premier index';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := '1';


    IF "Tjrs_1" THEN
        "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 1000;
    END_IF;
END_IF;
END_REGION


REGION 1000 : Gestion d'un nouvel enregitrement


// 1000 : Attente avant nouvel enregistrement
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 1000 THEN


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Attente avant nouvel enregistrement';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := 'Temps d echantillonage';


    (*ATTENTE DEMANDE DE SYNCHRO FIN DE PROGRAMME*)
    IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 1000 AND "DB200_SEQ_PROCESS".SEQ.NUM_ETAPE = 31020 THEN
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 1005;
    END_IF;


    //* Sauvegarde l'heure sur premier index
    IF "DB568_SEQ_ARCHIVAGE".SEQ.T_1S >= "DB569_PARAM_SEQ_ARCHIVAGE".tps_echantillonnage_int THEN
        "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 1100;
    END_IF;
END_IF;


(*ATTENTE DEMANDE DE SYNCHRO FIN DE PROGRAMME*)
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 1005 AND "DB200_SEQ_PROCESS".SEQ.NUM_ETAPE <> 31020 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 6000;
END_IF;


// 1100 : Controle de l'index
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 1100 THEN


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Controle index';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := 'Prochaine etape idientifiee';


    //Pas de défaut active - Archivage des premieres valeurs avant le temps defaut 
    IF "DB569_PARAM_SEQ_ARCHIVAGE".index < "DB569_PARAM_SEQ_ARCHIVAGE".Index_att_def + 1 THEN
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 2000;
    END_IF;


    //Pas de défaut active - Archivage des premieres valeurs apres le temps defaut
    IF "DB569_PARAM_SEQ_ARCHIVAGE".index = "DB569_PARAM_SEQ_ARCHIVAGE".Index_att_def + 1 THEN
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 3000;
    END_IF;


    //Défaut active - Archivage des valeurs 
    IF "DB50_DEF_GEN".DEF_0033 THEN
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 4000;
    END_IF;
END_IF;


END_REGION


REGION Pas de défaut active - Archivage des premieres valeurs avant le temps defaut


// 2000 : Energistrement de la donnée   
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 2000 THEN


    "DB580_ARCHIVAGE_PARAM_02".Archive["DB569_PARAM_SEQ_ARCHIVAGE".index] := "DB200_SEQ_PROCESS".SEQ.INT03;
    "DB581_ARCHIVAGE_PARAM_04".Archive["DB569_PARAM_SEQ_ARCHIVAGE".index] := "DB200_SEQ_PROCESS".SEQ.INT04;
    "DB569_PARAM_SEQ_ARCHIVAGE".index := "DB569_PARAM_SEQ_ARCHIVAGE".index + 1;


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Energistrement de la donnee et pas de perte de com';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := '1';


    IF "Tjrs_1" THEN
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 1000;
    END_IF;
END_IF;


END_REGION


REGION //Pas de défaut active - Archivage des premieres valeurs apres le temps defaut


// 3000 : Energistrement de la donnée   
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 3000 THEN
    "DB580_ARCHIVAGE_PARAM_02".Archive["DB569_PARAM_SEQ_ARCHIVAGE".index] := "DB200_SEQ_PROCESS".SEQ.INT03;
    "DB581_ARCHIVAGE_PARAM_04".Archive["DB569_PARAM_SEQ_ARCHIVAGE".index] := "DB200_SEQ_PROCESS".SEQ.INT04;


    FOR #i := 2 TO "DB569_PARAM_SEQ_ARCHIVAGE".Index_att_def + 1 DO
        "DB580_ARCHIVAGE_PARAM_02".Archive[#i - 1] := "DB580_ARCHIVAGE_PARAM_02".Archive[#i];
        "DB581_ARCHIVAGE_PARAM_04".Archive[#i - 1] := "DB581_ARCHIVAGE_PARAM_04".Archive[#i];
    END_FOR;


    "DB580_ARCHIVAGE_PARAM_02".Heure_debut := "DB580_ARCHIVAGE_PARAM_02".Heure_debut + "DB569_PARAM_SEQ_ARCHIVAGE".Tps_Echantillonnage;
    "DB581_ARCHIVAGE_PARAM_04".Heure_debut := "DB581_ARCHIVAGE_PARAM_04".Heure_debut + "DB569_PARAM_SEQ_ARCHIVAGE".Tps_Echantillonnage;


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Energistrement de la donnee et pas de pert de com';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := '1';


    IF "Tjrs_1" THEN
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 1000;
    END_IF;
END_IF;
END_REGION


REGION Défaut active - Archivage des valeurs


//4000 : Energistrement de la donnée  
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 4000 THEN


    "DB580_ARCHIVAGE_PARAM_02".Heure_debut := "DB580_ARCHIVAGE_PARAM_02".Heure_debut - "DB569_PARAM_SEQ_ARCHIVAGE".Tps_Echantillonnage;
    "DB581_ARCHIVAGE_PARAM_04".Heure_debut := "DB581_ARCHIVAGE_PARAM_04".Heure_debut - "DB569_PARAM_SEQ_ARCHIVAGE".Tps_Echantillonnage;


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Energistrement de la donnee et perte de com';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := '1';


    IF "Tjrs_1" THEN
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 4100;
    END_IF;
END_IF;


// 4100 : Attente avant nouvel enregistrement
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 4100 THEN


    IF "DB569_PARAM_SEQ_ARCHIVAGE".index <= "DB569_PARAM_SEQ_ARCHIVAGE".index_max THEN
        "DB580_ARCHIVAGE_PARAM_02".Archive["DB569_PARAM_SEQ_ARCHIVAGE".index] := "DB200_SEQ_PROCESS".SEQ.INT03;
        "DB581_ARCHIVAGE_PARAM_04".Archive["DB569_PARAM_SEQ_ARCHIVAGE".index] := "DB200_SEQ_PROCESS".SEQ.INT04;


        "DB569_PARAM_SEQ_ARCHIVAGE".index := "DB569_PARAM_SEQ_ARCHIVAGE".index + 1;
    END_IF;


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Nouvel enregistrement et perte de com';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := '1';


    //* Sauvegarde l'heure sur premier index
    IF "Tjrs_1" THEN
        "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 4200;
    END_IF;
END_IF;


// 4200 : Attente avant nouvel enregistrement
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 4200 THEN


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Attente avant nouvel echantillonnage et perte de com';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := '1';


    //* Sauvegarde l'heure sur premier index
    IF "DB568_SEQ_ARCHIVAGE".SEQ.T_1S >= "DB569_PARAM_SEQ_ARCHIVAGE".tps_echantillonnage_int THEN
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 4300;
    END_IF;
END_IF;


// 4300 : Attente avant nouvel enregistrement
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 4300 THEN


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'Verification defaut de com en cours';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := '1';


    (*ATTENTE DEMANDE DE SYNCHRO FIN DE PROGRAMME*)
    IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 4300 AND "DB200_SEQ_PROCESS".SEQ.NUM_ETAPE = 31020 THEN
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 4305;
        GOTO L990;
    END_IF;


    //* Defaut toujours en cours
    IF "DB50_DEF_GEN".DEF_0033 THEN
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        //"DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 4100;
    END_IF;


    //* Pas de Defaut  en cours ou programme terminé
    IF NOT "DB50_DEF_GEN".DEF_0033 THEN
        "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 5000;
    END_IF;
END_IF;


L990:
(*ATTENTE DEMANDE DE SYNCHRO FIN DE PROGRAMME*)
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 4305 AND "DB200_SEQ_PROCESS".SEQ.NUM_ETAPE <> 31020 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 5000;
END_IF;
END_REGION


REGION Synchronisation FTP


(*DEMANDE DE SYNCHRO EXPORT STP*)
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 5000 AND "DB570_SEQ_COM_FTP".SEQ.NUM_ETAPE = 35 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 5005;
END_IF;
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 5005 AND "DB570_SEQ_COM_FTP".SEQ.NUM_ETAPE <> 35 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 5010;
END_IF;


(*ATTENTE DEMANDE DE SYNCHRO FIN EXPORT FTP*)
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 5010 AND "DB570_SEQ_COM_FTP".SEQ.NUM_ETAPE = 1010 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 5015;
END_IF;
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 5015 AND "DB570_SEQ_COM_FTP".SEQ.NUM_ETAPE <> 1010 THEN
    "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 6000;
END_IF;


END_REGION


REGION RAZ des tableaux
// 6000 : RAZ des tableaux
IF "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE = 6000 THEN


    FOR #i := 1 TO 3600 DO
        "DB568_SEQ_ARCHIVAGE".SEQ.INT01 := #i;
        "DB580_ARCHIVAGE_PARAM_02".Archive[#i] := 0.0;
        "DB581_ARCHIVAGE_PARAM_04".Archive[#i] := 0.0;
    END_FOR;


    "DB569_PARAM_SEQ_ARCHIVAGE".index := 1;


    "DB568_SEQ_ARCHIVAGE".SEQ.NOM_ETAPE := 'RAZ des tableaux d archivage';
    "DB568_SEQ_ARCHIVAGE".SEQ.DESCRIP_TRANSITION := 'Verification process en cours ou non';

    IF "DB200_SEQ_PROCESS".SEQ.ETAT01 = 1 THEN
        "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 100;
    ELSE
        "DB568_SEQ_ARCHIVAGE".SEQ.T_100MS := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.T_1S := 0;
        "DB568_SEQ_ARCHIVAGE".SEQ.NUM_ETAPE := 10;
    END_IF;
END_IF;
END_REGION
//**********************************************************************************************************
L999:
;

Liens rapides

Solutions industrielles Automatisme, Électricité, Informatique

Découvrez tous les savoir-faire du Groupe API

Contactez-nous par-email